edit: ok, nie ma sprawy.
edit: Na prośbe wrzucam zaktualizowany skrypt na samej górze (jak się coś znowu zmieni to aktualizację wstawię od razu tutaj):
Kod: Zaznacz cały
; "cam.sqs", wersja 1.1
; Skrypt kamerki do robienia zrzutów ekranu [PrintScreen]
; aszek, 2009
; Składnia wywołania:
; [] exec "cam.sqs";
; Żadnych parametrów nie trzeba !
; Po kliknieciu na mapie, kamera się włacza we wskazanym miejscu
; Kamerą steruje się jak śmigłowcem
; Jeśli kamera zostanie przez chwilę na ziemi to automatycznie się wyłączy
? count _this == 0 : goto "cameraAssign";
_action = _this select 0;
? (_action == "cameraOn") : goto "cameraon";
? (_action == "cameraOff") : goto "cameraoff";
goto "end";
#cameraAssign
onMapSingleClick "[""cameraOn"",_pos] exec ""cam.sqs""; true;";
titleText ["Aby ustwic kamere wybierz miejsce na mapie.", "plain down", 1];
~3
titleText ["", "plain down", 1];
goto "end";
#cameraon
ShowCinemaBorder false;
_camPos = _this select 1;
cutText ["","BLACK OUT"];
cam = "camera" CamCreate [_camPos select 0, _camPos select 1, (_camPos select 2) + 3];
cam cameraEffect ["external", "back"];
cam camCommand "manual on";
cam camCommand "inertia off";
cam camSetFOV 1;
cam camCommit 0;
@CamCommitted cam;
cutText ["","BLACK IN"];
titleText ["Kamere uzywaj jak pojazdu latajacego.\nAby wylaczyc kamere zostaw ja przez chwile na ziemi.", "plain down", 1];
~5
titleText ["", "plain down", 1];
_tig = createTrigger ["EmptyDetector", _camPos];
_tig setTriggerType "NONE";
_tig setTriggerStatements ["this and (((getpos cam) select 2) < 0.3) and (((velocity cam) select 0) == 0) and (((velocity cam) select 1) == 0)", "[""cameraOff""] exec ""cam.sqs""", ""];
_tig setTriggerArea [50000, 50000, 0, false];
_tig setTriggerTimeout [5, 5, 5, true];
_tig setTriggerActivation ["ANY", "PRESENT", true];
@false;
#cameraoff
cutText ["","BLACK OUT"];
cam CameraEffect ["terminate","back"];
camDestroy cam;
cutText ["","BLACK IN"];
#end
exit;
http://www.armedassault.com.pl/viewtopi ... 7&start=11